subroutine ibsl_n19(ichn,alb_corr)
c
c     A copy of ibsl_n18 for N19 A&E.  11/2008
c
c     The N19 radiance anomaly due to IBSL at SZA > ~75 in north. 
c     Initial model was based on comparison of the inital profile
c     residue between N16 and N17, and the night side IBSL.  
c
c     The IBSL model for the day side uses the time dependence and 
c     the wavelength dependence from the night side.  Use the day side
c     comparison of the residue and the V6 c-sigma to derive the wavelength
c     independent goniometry depedence and the IBSL levels.  This code is
c     written for more general situations in testing of verious IBSL models.
c
c     corr =  c0_ibsl + c1_ibsl * (SCSEA - SCSEA_ref), 
c        for SCSEA > SCSEA_edge1 (-10) degrees, where SCSEA_ref = 6 degrees which
c     is given in the IBSL goniometry table.  
c     corr =  [c0_ibsl + c1_ibsl *(SCSEA_edge1 - SCSEA_ref)] * ibsl_edge(SCSEA)
c        for SCSEA in [SCSEA_edge0,SCSEA_edge1] ([-15,-10]) degrees, where
c     ibsl_edge(SCSEA) is the normalized rising edge of IBSL.  
c     c0_ibsl and c1_ibsl are dependent on wavelength, time and SCSAA(SCSEA_ref),
c     are assigned in subroutine get_ibsl,
c     c0_ibsl = [e0a(w) + e0b(w)*(SCSAA-SCSAA_ref) + e0c(w)*(SCSAA-SCSAA_ref)^2+...]*ibsl(w,t)
c     c1_ibsl = [e1a(w) + e1b(w)*(SCSAA-SCSAA_ref) + e1c(w)*(SCSAA-SCSAA_ref)^2+...]*ibsl(w,t)
c
c     The correction should be done in the calling program:       
c     albedo = albedo_raw - corr
c
c
c     Params    Type  I/O  comments
c     ichn      I*4   I    channel number
c     alb_corr  R*4   O    the anomaly correction to monochomator ichn-channel albedo
c        Input parameters from common blocks
c     scsea0    I*4   I    Spacecraft Centered Solar Elevation Angle (degrees*100) at t0
c     scsea1    I*4   I    Spacecraft Centered Solar Elevation Angle (degrees*100) at t0 + 32 s
c     scsaa0    I*4   I    Spacecraft Centered Solar Azmuth Angle (degrees*100) at t0
c     scsaa1    I*4   I    Spacecraft Centered Solar Azmuth Angle (degrees*100) at t0 + 32 s
c     frac      R*4   I    channel timing fraction in a scan for the interpolation of angles
c     dateyr    R*4   I    date in terms of fraction year
c        Internal variable
c     scsea     R*4   I    Spacecraft Centered Solar Elevation Angle at ichn
c     scsaa     R*4   I    Spacecraft Centered Solar Azmuth Angle at ichn
c
c
      include "const.inc"
      include "buffin.inc"
      include "ibsl_tabl.inc"
      real*4 scsea,alb_corr
      real*4 ri0,fr0,e,e_ccr,dsaa,g,g_ccr,t,t_ccr,scsea_ref_a
      integer*4 ichn,i0
c
      alb_corr=0.
c     
      if(scsea_edge100 .eq. 0) scsea_edge100=-1500
      if((scsea0 .gt. scsea_edge100) .and. (szenb .lt. szene))then
       if(cyri .ne. yearsc .or. cdyi .ne. daysc)then
        scsea=scsea0/100.
        scsaa=scsaa0/100.
c     As of Aug 31, 2011, the data were limited.  The fitted polynomial can
c     not be used to extrapolate IBSL scsaa dependence.  
        if(scsaa .lt. 57.5) scsaa=57.5
        if(scsaa .gt. 73.5) scsaa=73.5
        call get_ibsl(yearsc,daysc,scsea,scsaa)
       endif
       scsea=(scsea0+(scsea1-scsea0)*frac(ichn))/100.
       if(scsea .ge. scsea_edge0)then
        scsaa=(scsaa0+(scsaa1-scsaa0)*frac(ichn))/100.
        if(scsea .lt. scsea_edge1)then
         ri0=(scsea-scsea_edge0)/dp_edge+1
         i0=int(ri0)
         fr0=(ri0-i0)
         alb_corr=(edge(i0)+(edge(i0+1)-edge(i0))*fr0)*ibsl_edge(ichn)
        else
         alb_corr=c0_ibsl(ichn)+c1_ibsl(ichn)*(scsea-scsea_ref)
        endif
       endif
      endif
c      if(alb_corr .ne. 0)then 
c        write(6,*) 'ibsl_n18: ',ichn,scsea,alb_corr
c      endif
c
      return
      end